Tjyylli

I Need to create a program that will check for and install important updates

Would it be possible to have it only create a popup when updates are available?

Currently I am using this code to check for updates:

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.

' This code has been placed in the public domain.  It may be freely

' used, modified, and distributed.  However it is provided with no

' warranty, either express or implied.

'

' Exit Codes:

'   0 = scripting failure

'   1 = error obtaining or installing updates

'   2 = installation successful, no further updates to install

'   3 = reboot needed; rerun script after reboot

'

' Note that exit code 0 has to indicate failure because that is what

' is returned if a scripting error is raised.

'



Set updateSession = CreateObject("Microsoft.Update.Session")



Set updateSearcher = updateSession.CreateUpdateSearcher()

Set updateDownloader = updateSession.CreateUpdateDownloader()

Set updateInstaller = updateSession.CreateUpdateInstaller()



Do



  WScript.Echo

  WScript.Echo "Searching for approved updates ..."

  WScript.Echo



  Set updateSearch = updateSearcher.Search("IsInstalled=0")



  If updateSearch.ResultCode <> 2 Then



    WScript.Echo "Search failed with result code", updateSearch.ResultCode

    WScript.Quit 1



  End If



  If updateSearch.Updates.Count = 0 Then



    WScript.Echo "There are no updates to install."

    WScript.Quit 2



  End If



  Set updateList = updateSearch.Updates



  For I = 0 to updateSearch.Updates.Count - 1



    Set update = updateList.Item(I)



    WScript.Echo "Update found:", update.Title



  Next



  WScript.Echo



  updateDownloader.Updates = updateList

  updateDownloader.Priority = 3



  Set downloadResult = updateDownloader.Download()



  If downloadResult.ResultCode <> 2 Then



    WScript.Echo "Download failed with result code", downloadResult.ResultCode

    WScript.Echo



    WScript.Quit 1



  End If



  WScript.Echo "Download complete.  Installing updates ..."

  WScript.Echo



  updateInstaller.Updates = updateList



  Set installationResult = updateInstaller.Install()



  If installationResult.ResultCode <> 2 Then



    WScript.Echo "Installation failed with result code", installationResult.ResultCode



    For I = 0 to updateList.Count - 1



      Set updateInstallationResult = installationResult.GetUpdateResult(I)

      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode



    Next



    WScript.Quit 1



  End If



  If installationResult.RebootRequired Then



    WScript.Echo "The system must be rebooted to complete installation."



    WScript.Quit 3



  End If



  WScript.Echo "Installation complete."



Loop

The Windows Update API is quite powerful, however it is not easy to determine which update is acutally "important" - your code shows a very simple search for all updates that are not yet installed. You can list the update packages and query the properties of the IUpdate Interfaces (see http://msdn.microsoft.com/en-us/library/windows/desktop/aa386099(v=vs.85).aspx)

You can also have a look at WuInstall (there was a free version a while ago, but they put it off the website, now only a commercial version with a free trial is availalbe) - it does also utilize the Windows Update API in a command line tool. See http://www.wuinstall.com/ and http://help.wuinstall.com/en/index.html

Basically, you can do many (not all) things that WuInstall can do also with the Windows Update API, but it might save you a lot of time of programming and debugging.

What do you mean with "create a popup", by the way?